//lorenz constants
var step:Number = 0.005;
var sigma:Number = 10.0;
var rho:Number = 28.0;
var beta:Number = 8.0 / 3.0;
 
//lorenz equation:
x1=x0+step*sigma*(y0-x0);
y1=y0+step*(x0*(rho-z0)-y0);
z1=z0+step*(x0*y0-beta*z0);
 
x0=x1;
y0=y1;
z0=z1;

mouseDistance = Math.sqrt( xdiff * xdiff + ydiff * ydiff);
current.scaleX = current.scaleY =  Math.min( 4.0, (  mouseDistance / 700) * 4.0);

var t:Number = N;
var a:Number = 9;
var b:Number = 8;
var S:Number = t * (Math.PI / 2);
 
var x:Number = xx * Math.sin( a * t + S );
var y:Number = yy * Math.sin(b * t);
var z:Number = zz * Math.cos((a/b)*S);

package 
{
	import flash.media.SoundTransform;
	import flash.events.IOErrorEvent;
	import flash.events.ProgressEvent;
	import flash.events.Event;
	import flash.net.URLRequest;
	import flash.utils.Dictionary;
	import flash.media.Sound;
	import flash.media.SoundChannel;
 
	/**
	 * @author  RACKDOLL
	 * @version 1.0
	 * @usage
	 * SoundManager.getInstance().addSound  ( "yourSoundID", "yourSoundPath" );
	 * SoundManager.getIinstance().playSound( "yourSoundID", yourVolume, yourRepeatCount );
	 * SoundManager.getInstance().stopSound ( "yourSoundID" );
	 */
	public class SoundManager
	{
		public var sounds           :Dictionary   = null;
		public var currPlayingSounds:Dictionary   = null;
 
 
 
 
 
 
//***************************************************************************
// 					C O N S T R U C T O R
//***************************************************************************
		public function SoundManager()
		{
			sounds 			  = new Dictionary();
			currPlayingSounds = new Dictionary();
		}
 
		// --> SINGLETON:
		private static var _instance:SoundManager;
		public static function getInstance():SoundManager 
		{
			if(!_instance )_instance = new SoundManager();
			return _instance;
		}
 
 
 
 
 
 
 
 
 
 
//***************************************************************************
// 					A D D  /  R E M O V E
//***************************************************************************		
 
 
		//-------------------------------
		//  ADD SOUND WITH ID:
		//-------------------------------
		public function addSound( $id:String, $url:String):void 
		{
			sounds[$id] = $url;
		}
 
 
 
 
 
		//-------------------------------
		//  REMOVE SOUND WITH ID:
		//-------------------------------
		public function removeSound( $id:String ):void 
		{
			var id:String;
 
			//1.
			//check current playing sounds dictionary for sound:
			for( id in currPlayingSounds){
				if( id == $id ){
					delete currPlayingSounds[id];
					break;
				}
			}
 
 
			//2.
			//check all sounds dictionary for sound:
			for( id in sounds){
				if( id == $id ){
					delete sounds[id];
					break;
				}
			}
		}
 
 
 
 
 
 
 
 
 
//***************************************************************************
// 					P L A Y  /  S T O P
//***************************************************************************		
 
 
		//-------------------------------
		//  PLAY SOUND WITH ID:
		//-------------------------------
		public function playSound( $id:String, $volume:Number = 1.0, $timesToRepeat:int = 999 ):void 
		{
			//first check if it alrdy excists, if so...start it!
			var t:SoundTransform;
			for( var id:String in currPlayingSounds){
 
				if( id == $id ){
					var c:SoundChannel  = currPlayingSounds[id].channel as SoundChannel;
					var s:Sound         = currPlayingSounds[id].sound as Sound;
					t = new SoundTransform($volume);
					c = s.play(0, $timesToRepeat);
					c.soundTransform = t;
					currPlayingSounds[id] = { channel: c, sound: s, volume: $volume };
					return;
				}
			}
 
 
			//---
			//If we come here, it means we have a new sound!
 
			//setup sound:
			var req:URLRequest = new URLRequest( sounds[$id] );
			var soundFactory:Sound = new Sound();
			soundFactory.addEventListener(Event.COMPLETE	    , onSoundFactoryComplete );
			soundFactory.addEventListener(ProgressEvent.PROGRESS, onSoundFactoryProgress );
			soundFactory.addEventListener(IOErrorEvent.IO_ERROR , onIOError );
 
			//load sound:
			soundFactory.load( req );
 
			//play sound:
			var channel:SoundChannel = new SoundChannel();
			channel = soundFactory.play(0, $timesToRepeat);
 
			//set volume:
			t = new SoundTransform($volume);
			channel.soundTransform = t;
 
 
			//save soound in current playing sounds:
			currPlayingSounds[ $id ] = { channel: channel, sound: soundFactory, volume: $volume  };
		}
 
 
 
 
 
 
 
 
		//-------------------------------
		//STOP SOUND WITH ID:
		//-------------------------------
		public function stopSound( $id:String ):void 
		{
			for( var id:String in currPlayingSounds ){
				trace( id );
				if( id == $id ){
					SoundChannel( currPlayingSounds[id].channel ).stop();
				}
			}
		}
 
 
 
 
 
 
 
 
 
//***************************************************************************
// 					V O L U M E
//***************************************************************************
 
		//-------------------------------
		// SET ALL SOUND VOLUMES:
		//-------------------------------
		public function setGlobalVolume( $volume:Number ):void 
		{
			for( var id:String in currPlayingSounds ){
					var s:SoundTransform = new SoundTransform($volume);
					SoundChannel( currPlayingSounds[id].channel ).soundTransform = s;
					currPlayingSounds[id].volume = $volume;
				}
		}
 
 
 
 
 
		//-------------------------------
		// TOGGLE MUTE ALL SOUNDS:
		//-------------------------------
		public function muteAll( $mute:Boolean = true ):void
		{
			if( $mute ) {
				setGlobalVolume(0.0);
			}
			else
			{
				for( var id:String in currPlayingSounds){
					var s:SoundTransform = new SoundTransform(currPlayingSounds[id].volume);
					SoundChannel( currPlayingSounds[id].channel ).soundTransform = s;
				}
			}
		}
 
 
 
 
 
 
		//-------------------------------
		// SET SOUND VOLUME BY SOUND ID:
		//-------------------------------
		public function setVolume( $id:String, $volume:Number ):void 
		{
			for( var id:String in currPlayingSounds){
				if( id == $id ){
					var s:SoundTransform = new SoundTransform($volume);
					SoundChannel( currPlayingSounds[id].channel ).soundTransform = s;
					currPlayingSounds[id].volume = $volume;
				}
			}
		}
 
 
 
 
 
 
//***************************************************************************
// 			 R E A D I N G _ P R O P E R T I E S
//***************************************************************************		
 
 
 
		//-------------------------------
		// GET SOUND CHANNEL BY SOUND ID:
		//-------------------------------
		public function getSoundChannel( $id:String ):SoundChannel 
		{
			for( var id:String in currPlayingSounds){
				if( id == $id ){
					return SoundChannel( currPlayingSounds[id].channel );
				}
			}
			throwError(ERROR_NON_EXCISTENT_CHANNEL);
			return null;
		}
 
 
 
 
 
 
		//-------------------------------
		// GET SOUND TRANSFORM BY SOUND ID:
		//-------------------------------
		public function getSoundTransform( $id:String ):SoundTransform 
		{
			for( var id:String in currPlayingSounds){
				if( id == $id ){
					return SoundChannel( currPlayingSounds[id].channel ).soundTransform;
				}
			}
			throwError(ERROR_NON_EXCISTENT_TRANSFORM);
			return null;
		}
 
 
 
 
 
 
		//-------------------------------
		// GET SOUND VOLUME BY SOUND ID:
		//-------------------------------
		public function getSoundVolume( $id:String ):Number 
		{
			for( var id:String in currPlayingSounds){
				if( id == $id ){
					return currPlayingSounds[id].volume;
				}
			}
			throwError(ERROR_NON_EXCISTENT_VOLUME);
			return NaN;
		}
 
 
 
 
 
 
 
 
 
//***************************************************************************
// 					H A N D L E R S
//***************************************************************************
		public static const ERROR_NON_EXCISTENT_CHANNEL   :String = "You are trying to get a non excistent soundChannel!\nPlay it first in order to assign a channel!";
		public static const ERROR_NON_EXCISTENT_VOLUME    :String = "You are trying to get a non excistent volume!\nPlay it first in order to assign a volume!";
		public static const ERROR_NON_EXCISTENT_TRANSFORM :String = "You are trying to get a non excistent soundTransform!\nPlay it first in order to assign a transform!";
		public static const ERROR_IO					  :String = "There is an I-O error!";
		private function throwError( $error:String = "undefined_error" ):void 
		{
			throw Error("*** --> SOUND WARNING: "+$error+"<-- ***");
		}
		private function onSoundFactoryComplete(e:Event = null):void
		{
			trace("sound complete!");
		}
		private function onSoundFactoryProgress(e:Event = null ):void 
		{
			trace("sounnd progress!");	
		}
		private function onIOError(e:Event = null ):void 
		{
			throwError( ERROR_IO );	
		}
	}
}